activePDF WebGrabber - Beispiel-Code und HowTo's

Mehrere URL's in einer PDF-Datei zusammenfügen

Dieses Beispiel konvertiert fünf Seite der Google.com Webseite einzeln und fügt sie an eine Datei namens mu ltipleURLs.pdf an.

<%
'Array of the URLs for Conversion
httpArray = Array("http://www.google.com", _
"http://images.google.com", _
"http://www.deja.com", _
"http://directory.google.com", _
"http://news.google.com")

'Create the Server and WebGrabber objects
Set WG = Server.CreateObject("APWebGrabber.Object")
Set APS = Server.CreateObject("APServer.Object")

'START SETTINGS-----------------------------------------------

'SERVER SETTINGS
APS.OutputDirectory Server.MapPath(".")
APS.NewDocumentName "MultipleURLs.pdf"
APS.ConcatenateToExisting = True

'WEBGRABBER SETTINGS
'0 for Native engine, 1 for IE engine
WG.EngineToUse = 0
'Only used for Native engine
WG.PrintBackgroundColors = 3

'END SETTINGS-------------------------------------------------

'Go through each URL and perform the conversion appending
'each conversion to the file named "multipleURLs.pdf"

For i = 0 To UBound(httpArray)

WG.URL = httpArray(i)

'Needed to pass Server properties
WG.Prt2DiskSettings = APS.ToString()

r = WG.DoPrint("127.0.0.1", 64320)
r = WG.Wait("127.0.0.1", 64320, 300, "")

'Check for error
If r <> "019" Then
Response.Write "error occured, code: " & r
End If

Next

'Check for successful conversion
If r = "019" Then
Response.Write "Successful"
End If

'Clean everything from memory
r = WG.Cleanup("127.0.0.1", 64320)

'Set objects to nothing
Set WG = Nothing
Set APS = Nothing
%>

nach oben

Aufruf von einem Remote Computer

Um Aufträge von einem Remote Computer abzuschicken, muss sowohlactivePDF Server als auch activePDF WebGrabber auf dem Server installiert sein. Zusätzlich muss das WebGrabber OCX auf dem Remote Computer installiert sein. Das WebGrabber OCX enthält das APServer Objekt, das es dem activePDF Server erlaubt in Verbindung mit dem WebGrabber zu arbeiten. Es sit wichtig, die APServer Methode LoadRemoteProfile zu verwenden um die Übergabe von Parametern zu erlauben. Die IP Parameter (für LoadRemoteProfile, DoPrint, Wait, and Cleanup methods) müssen auf die IP Adresse des Servers gesetzt werden auf dem activePDF Server und WebGrabber laufen.

<%
'Create Server and WebGrabber objects
'Both objects can be used with the WebGrabber OCX install

Set WG = Server.CreateObject("APWebGrabber.Object")
Set APS = Server.CreateObject("APServer.Object")

'--------------------------Variables------------------------------

'IP of the machine with Full version of WG and SVR
strIP = "192.168.1.1"

'Timeout variable for all timeouts
strTimeout = 300

'Location to place created PDF
'NOTE: must be a location the Server has access to place the file
strOutputPath = "c:\"

'URL to convert
strURL = "http://www.yahoo.com"

'--------------------------Variables------------------------------

'WEBGRABBER PROPERTIES
WG.URL = strURL
WG.TimeOut = strTimeout
WG.PrinterTimeout = strTimeout

'SERVER PROPERTIES USED IN CONJUNCTION WITH WG
'LoadRemoteProfile tells WG where to send the Server Settings
APS.LoadRemoteProfile strIP
APS.OutputDirectory strOutputPath
APS.PDFTimeout = strTimeout

'Send the Settings to the server
WG.Prt2DiskSettings = APS.ToString()

'Start the job and wait
r = WG.DoPrint(strIP, 64320)
r = WG.Wait(strIP, 64320, strTimeout, "")

'Check for Successful conversion
If r = "019" Then
Response.Write "Success, output location: '" & strOutputPath & "'"
Else
Response.Write "Failure: " & r
End If

'Cleanup the memory space used
r = WG.Cleanup(strIP, 64320)

'Set the objects to Nothing
Set WG = Nothing
Set APS = Nothing
%>

nach oben